Go Beyond the Smart Editor using Smart Forms

Copy the code below to create your own Arcade calculated expressions:

// Define the source layer to intersect
var sourceLayer = FeatureSetByName($map, "Addresses")
// Count the number of intersecting features from the source layer
var countFeatures = Count(Intersects(sourceLayer,$feature))
// Return the value (number)
return countFeatures

Copy the code below to create your own Arcade calculated expressions:

// Return the geodetic area for a polygon feature in the given units,
// and round to 0 decimals
Round(AreaGeodetic($feature, 'square-feet'),0)

Copy the code below to create your own Arcade calculated expressions:

// Define the source layer to fetch attribute values
var sourceLayer = FeatureSetByName($map, "Public School Locations")
// Get the features contained in the current feature's boundaries
var attributeValues = Contains($feature, sourceLayer)
// Loop through the features and get values for the field "NAME"
var valuesList = []
for (var f in attributeValues){
    Push(valuesList, f.NAME)
}
// Return the list of values, separated by a comma
return Concatenate(valuesList, ', ')

Copy the code below to create your own Arcade calculated expressions:

// Define the text field to look up
var text_field = $feature.ConcatenateValues
  // Find the text value "High" within the text field 
if (Find("High", text_field, 0)>-1) {
  // If the string value "High" can be found, return 'Yes'
  return "Yes";  
  // If the value "High" cannot be found, return 'No'
} else {
  return "No";  
}

Copy the code below to create your own Arcade calculated expressions:

// Define the edit context so the value is only calculated when the feature is created
if ($editContext.editType == "INSERT") {
  // Lookup the value for the last created feature
  var last_feature = First(OrderBy($layer, 'SequentialValue DESC'));
  // If the last value was empty write 1, otherwise add 1 to the value
  return IIf(IsEmpty(last_feature), 1, last_feature.SequentialValue + 1)
} else {
  // When the feature is updated, return the existing value in this field
  // and do not calculate a new value
  $feature.SequentialValue
}

Copy the code below to create your own Arcade calculated expressions:

// New function to generate a random number that must be above the value "val"
function random_above(val) { 
  // Generate a random number between 0 and 1
  var random_number = Random()
  // If the number is below "val", generate a new random number
  if (random_number <= val) { 
    return random_above(val) 
  }
  // If the number is above "val". multiply by 100,000 and remove decimals
  return Round(random_number *100000, 0)
} 
// Define the edit context so the value is only calculated when the feature is created
// and return the result from the function "random_above" when "val"= 0.1
if ($editContext.editType == "INSERT" && $feature.RandomValue == null) {
  return random_above(0.1) 
} else { 
  // When the feature is updated, return the existing value in this field
  // and do not calculate a new random value
  return $feature.RandomValue
}

Copy the code below to create your own Arcade calculated expressions:

// Define the edit context so the value is only calculated when the feature is created
if ($editContext.editType == "INSERT" && $feature.RandomValueText == null) {
  // Generate a random number between 0 and 1, 
  // multiply it by 100,000 and preserve 5 digits
  var random_text = Text(Random()*100000, '00000')
  // Return the random number and add a prefix text to it
  return "Prefix-" + random_text
} else {
  // When the feature is updated, return the existing value in this field
  // and do not calculate a new random value
  $feature.RandomValueText
}